privateClouds
Summary
Details
Azure VMware Solution の Azure Service Health 通知とアラートを構成する
Impact: High Category: Monitoring and Alerting PG Verified: Verified
Description:
使用されているすべてのリージョンとサブスクリプションにわたって、Azure Service Health 通知が Azure VMware Solution に設定されていることを確認します。これにより、サービス/セキュリティの問題と、ホストの交換やアップグレードなどのメンテナンス アクティビティが伝達され、サービス リクエストの送信が削減されます。
Potential Benefits:
Prompt mitigation of issues.
Learn More:
ARG Query:
Click the Azure Resource Graph tab to view the query
// Azure Resource Graph Query
// Provides a list of Azure VMware Solution resources that don't have one or more service health alerts covering AVS private clouds in the deployed subscription and region pairs.
//full list of private clouds
(resources
| where ['type'] == "microsoft.avs/privateclouds"
| extend locale = tolower(location)
| extend subscriptionId = tolower(subscriptionId)
| project id, name, tags, subscriptionId, locale)
| join kind=leftouter
//Alert ID's that include all incident types filtered by AVS Service Health alerts
((resources
| where type == "microsoft.insights/activitylogalerts"
| extend alertproperties = todynamic(properties)
| where alertproperties.condition.allOf[0].field == "category" and alertproperties.condition.allOf[0].equals == "ServiceHealth"
| where alertproperties.condition.allOf[1].field == "properties.impactedServices[*].ServiceName" and set_has_element(alertproperties.condition.allOf[1].containsAny, "Azure VMware Solution")
| extend locale = strcat_array(split(tolower(alertproperties.condition.allOf[2].containsAny),' '), '')
| mv-expand todynamic(locale)
| where locale != "global"
| project subscriptionId, tostring(locale) )
| union
//Alert ID's that include only some of the incident types after filtering by service health alerts covering AVS private clouds.
(resources
| where type == "microsoft.insights/activitylogalerts"
| extend subscriptionId = tolower(subscriptionId)
| extend alertproperties = todynamic(properties)
| where alertproperties.condition.allOf[0].field == "category" and alertproperties.condition.allOf[0].equals == "ServiceHealth"
| where alertproperties.condition.allOf[2].field == "properties.impactedServices[*].ServiceName" and set_has_element(alertproperties.condition.allOf[2].containsAny, "Azure VMware Solution")
| extend locale = strcat_array(split(tolower(alertproperties.condition.allOf[3].containsAny),' '), '')
| mv-expand todynamic(locale)
| mv-expand alertproperties.condition.allOf[1].anyOf
| extend incidentType = alertproperties_condition_allOf_1_anyOf.equals
| where locale != "global"
| project id, subscriptionId, locale, incidentType
| distinct subscriptionId, tostring(locale), tostring(incidentType)
| summarize incidentTypes=count() by subscriptionId, locale
| where incidentTypes == 5 //only include this subscription, region pair if it includes all the incident types.
| project subscriptionId, locale)) on subscriptionId, locale
| where subscriptionId1 == "" or locale1 == "" or isnull(subscriptionId1) or isnull(locale1)
| project recommendationId = "74fcb9f2-9a25-49a6-8c42-d32851c4afb7", name, id, tags, param1 = "avsServiceHealthAlertsAllIncidentTypesConfigured: False"
Azure VMware Solution Private Cloud が容量制限に達する時期を監視する
Impact: Medium Category: Monitoring and Alerting PG Verified: Verified
Description:
Azure VMware Solution プライベート クラウドのノード数が 90 ホスト以上になったときにアラートを設定し、新しいプライベート クラウドをタイムリーに計画できるようにします。
Potential Benefits:
Proactive capacity planning
Learn More:
ARG Query:
Click the Azure Resource Graph tab to view the query
// cannot be validated with ARG
Azure VMware Solution クラスター サイズがホスト制限に近づいたときを監視する
Impact: Medium Category: Monitoring and Alerting PG Verified: Verified
Description:
クラスター サイズが 14 ホストに達するとアラートが発行されます。特にストレージのニーズによる増加に伴う新しいクラスターまたはデータストアを計画するために、定期的なアラートを設定します。ホストが 14 を超えると、新しいホストが追加されるたびにアラートをトリガーして、リソースをプロアクティブに監視します。
Potential Benefits:
Proactive resource management
Learn More:
ARG Query:
Click the Azure Resource Graph tab to view the query
// cannot be validated with ARG
vSAN データストアのマルチ AZ 可用性のためにストレッチ クラスターを有効にする
Impact: Low Category: High Availability PG Verified: Verified
Description:
Azure VMware ソリューションの場合、ストレッチ クラスターを有効にすると、99.99% の SLA、同期ストレージ レプリケーション (RPOu003d0) が提供され、vSAN データストアが 2 つの AZ に分散されます。初期セットアップ時に実行する必要があり、AZ 間での拡張により 2 倍のクォータが必要になります。
Potential Benefits:
99.99% SLA, 0 RPO, Multi-AZ
Learn More:
ARG Query:
Click the Azure Resource Graph tab to view the query
// Azure Resource Graph Query
// Provides a list of Azure VMware Solution resources that aren't configured as stretched clusters and in supported regions.
resources
| where ['type'] == "microsoft.avs/privateclouds"
| extend avsproperties = todynamic(properties)
| where avsproperties.availability.strategy != "DualZone"
| where location in ("uksouth", "westeurope", "germanywestcentral", "australiaeast")
| project recommendationId = "9ec5b4c8-3dd8-473a-86ee-3273290331b9", name, id, tags, param1 = "stretchClusters: Disabled"
vSAN データストア使用率の Azure Monitor アラート警告しきい値を構成する
Impact: High Category: Monitoring and Alerting PG Verified: Verified
Description:
ストレージ使用率を監視し、70% と 75% の使用率にアラートを設定して容量計画を可能にすることで、VMware vSAN データストアのスラック スペースが SLA に合わせて維持されるようにします。拡張するには、CPU と RAM の要件が満たされている場合、ホストまたは Azure Elastic SAN、Azure NetApp Files などの外部ストレージを追加します。
Potential Benefits:
Optimized capacity planning for vSAN
Learn More:
ARG Query:
Click the Azure Resource Graph tab to view the query
// Azure Resource Graph Query
// Provides a list of Azure VMware Solution resources that don't have a vSAN capacity critical alert with a threshold of 75% or a warning capacity of 70%.
(
resources
| where ['type'] == "microsoft.avs/privateclouds"
| extend scopeId = tolower(tostring(id))
| project ['scopeId'], name, id, tags
| join kind=leftouter (
resources
| where type == "microsoft.insights/metricalerts"
| extend alertProperties = todynamic(properties)
| mv-expand alertProperties.scopes
| mv-expand alertProperties.criteria.allOf
| extend scopeId = tolower(tostring(alertProperties_scopes))
| extend metric = alertProperties_criteria_allOf.metricName
| extend threshold = alertProperties_criteria_allOf.threshold
| project scopeId, tostring(metric), toint(['threshold'])
| where metric == "DiskUsedPercentage"
| where threshold == 75
) on scopeId
| where isnull(['threshold'])
| project recommendationId = "4232eb32-3241-4049-9e14-9b8005817b56", name, id, tags, param1 = "vsanCapacityCriticalAlert: isNull or threshold != 75"
)
| union (
resources
| where ['type'] == "microsoft.avs/privateclouds"
| extend scopeId = tolower(tostring(id))
| project ['scopeId'], name, id, tags
| join kind=leftouter (
resources
| where type == "microsoft.insights/metricalerts"
| extend alertProperties = todynamic(properties)
| mv-expand alertProperties.scopes
| mv-expand alertProperties.criteria.allOf
| extend scopeId = tolower(tostring(alertProperties_scopes))
| extend metric = alertProperties_criteria_allOf.metricName
| extend threshold = alertProperties_criteria_allOf.threshold
| project scopeId, tostring(metric), toint(['threshold'])
| where metric == "DiskUsedPercentage"
| where threshold == 70
) on scopeId
| where isnull(['threshold'])
| project recommendationId = "4232eb32-3241-4049-9e14-9b8005817b56", name, id, tags, param1 = "vsanCapacityWarningAlert: isNull or threshold != 70"
)
Azure VMware ソリューションの診断設定で Syslog を構成する
Impact: High Category: Monitoring and Alerting PG Verified: Verified
Description:
分析やアーカイブのために syslog を外部ソースに送信するように、プライベート クラウドごとに診断設定が構成されていることを確認します。 Azure VMware Solution Syslog には、トラブルシューティングとパフォーマンスのデータが含まれており、迅速な問題解決と問題の早期検出に役立ちます。
Potential Benefits:
Faster issue resolution, early detection
Learn More:
ARG Query:
Click the Azure Resource Graph tab to view the query
// cannot be validated with ARG
CPU 使用率を監視して、ワークロードに十分なリソースを確保します。
Impact: Medium Category: Monitoring and Alerting PG Verified: Verified
Description:
Azure VMware ソリューションでは、動的ワークロード リソース管理に vSphere DRS と HA を利用し、ホスト リソースの枯渇を避けるために十分なコンピューティング リソースを確保します。ただし、CPU 使用率が 95% を超える状態が続くと、CPU Ready 時間が増加し、ワークロードに影響を与える可能性があります。
Potential Benefits:
Avoids resource exhaustion, optimizes performance
Learn More:
ARG Query:
Click the Azure Resource Graph tab to view the query
// Azure Resource Graph Query
// Provides a list of Azure VMware Solution resources that don't have a Cluster CPU capacity critical alert with a threshold of 95%.
resources
| where ['type'] == "microsoft.avs/privateclouds"
| extend scopeId = tolower(tostring(id))
| project ['scopeId'], name, id, tags
| join kind=leftouter (
resources
| where type == "microsoft.insights/metricalerts"
| extend alertProperties = todynamic(properties)
| mv-expand alertProperties.scopes
| mv-expand alertProperties.criteria.allOf
| extend scopeId = tolower(tostring(alertProperties_scopes))
| extend metric = alertProperties_criteria_allOf.metricName
| extend threshold = alertProperties_criteria_allOf.threshold
| project scopeId, tostring(metric), toint(['threshold'])
| where metric == "EffectiveCpuAverage"
| where threshold == 95
) on scopeId
| where isnull(['threshold'])
| project recommendationId = "4ee5d535-c47b-470a-9557-4a3dd297d62f", name, id, tags, param1 = "hostCpuCriticalAlert: isNull or threshold != 95"
メモリ使用率を監視して、ワークロードに十分なリソースを確保します
Impact: Medium Category: Monitoring and Alerting PG Verified: Verified
Description:
Azure VMware Solution でのホスト リソースの枯渇を防ぐために、十分なメモリ リソースを確保してください。動的なワークロード管理に vSphere DRS と vSphere HA を使用します。ただし、メモリの使用率が 95% を超え続けると、ディスクのスワップが発生し、ワークロードに影響を及ぼします。
Potential Benefits:
Avoids host exhaustion and swapping
Learn More:
ARG Query:
Click the Azure Resource Graph tab to view the query
// Azure Resource Graph Query
// Provides a list of Azure VMware Solution resources that don't have a cluster host memory critical alert with a threshold of 95%.
resources
| where ['type'] == "microsoft.avs/privateclouds"
| extend scopeId = tolower(tostring(id))
| project ['scopeId'], name, id, tags
| join kind=leftouter (
resources
| where type == "microsoft.insights/metricalerts"
| extend alertProperties = todynamic(properties)
| mv-expand alertProperties.scopes
| mv-expand alertProperties.criteria.allOf
| extend scopeId = tolower(tostring(alertProperties_scopes))
| extend metric = alertProperties_criteria_allOf.metricName
| extend threshold = alertProperties_criteria_allOf.threshold
| project scopeId, tostring(metric), toint(['threshold'])
| where metric == "UsageAverage"
| where threshold == 95
) on scopeId
| where isnull(['threshold'])
| project recommendationId = "029208c8-5186-4a76-8ee8-6e3445fef4dd", name, id, tags, param1 = "hostMemoryCriticalAlert: isNull or threshold != 95"
プライベート クラウドをホストするリソース グループにリソース削除ロックを適用します。
Impact: High Category: Governance PG Verified: Verified
Description:
Azure VMware Solution Private Cloud リソース グループにリソース削除ロックを適用すると、共同作成者アクセス権を持つユーザーによる不正な削除や誤った削除が防止され、Azure VMware Solution Private Cloud の保護と信頼性が確保されます。
Potential Benefits:
Prevents accidental deletion
Learn More:
ARG Query:
Click the Azure Resource Graph tab to view the query
// cannot be validated with ARG
vSAN データストアのカスタマー マネージド キーにキーの自動ローテーションを使用する
Impact: High Category: Security PG Verified: Verified
Description:
vSAN データストアの暗号化にカスタマー マネージド キーを使用する場合は、一元管理に Azure Key Vault を利用し、プライベート クラウドにリンクされたマネージド ID を介してキーにアクセスすることをお勧めします。これらのキーの有効期限が切れると、vSAN データストアとそれに関連するワークロードにアクセスできなくなる可能性があります。
Potential Benefits:
Avoid outages with key auto-rotation
Learn More:
ARG Query:
Click the Azure Resource Graph tab to view the query
// cannot be validated with ARG
プライベート FQDN ゾーンごとに複数の DNS サーバーを使用する
Impact: High Category: High Availability PG Verified: Verified
Description:
Azure VMware Solution プライベート クラウドは、1 つの FQDN に対して最大 3 つの DNS サーバーをサポートし、1 つの DNS サーバーが障害点になることを防ぎます。各プライベート クラウドからオンプレミスの FQDN 解決を行うには、複数の DNS サーバーを使用することが重要です。
Potential Benefits:
Enhances reliability and avoids failure
Learn More:
ARG Query:
Click the Azure Resource Graph tab to view the query
// cannot be validated with ARG