publicIPAddresses
Summary
Details
該当する場合は、標準 SKU とゾーン冗長 IP を使用します
Impact: High Category: High Availability PG Verified: Verified
Description:
Azure のパブリック IP アドレスは、Standard SKU であり、非ゾーン、ゾーン、またはゾーン冗長として利用できます。ゾーン冗長 IP はすべてのゾーンにわたってアクセス可能であり、単一ゾーンの障害に耐えることにより、より高い復元力を提供します。
Potential Benefits:
Enhanced resilience with zone redundancy
Learn More:
ARG Query:
Click the Azure Resource Graph tab to view the query
// Azure Resource Graph query
// List public IP addresses that are not Zone-Redundant
Resources
| where type =~ "Microsoft.Network/publicIPAddresses" and sku.tier =~ "Regional"
| where isempty(zones) or array_length(zones) <= 1
| extend az = case(isempty(zones), "Non-zonal", array_length(zones) <= 1, strcat("Zonal (", strcat_array(zones, ","), ")"), zones)
| project recommendationId = "c63b81fb-7afc-894c-a840-91bb8a8dcfaf", name, id, tags, param1 = strcat("sku: ", sku.name), param2 = strcat("availabilityZone: ", az)
SNAT の枯渇を避けるために、送信接続に NAT ゲートウェイを使用する
Impact: Medium Category: High Availability PG Verified: Verified
Description:
仮想ネットワークからの送信トラフィックに NAT ゲートウェイを採用することで、SNAT ポートの枯渇による接続障害を防ぎ、動的なスケーリングと安全なインターネット接続を確保します。
Potential Benefits:
Avoids SNAT port exhaustion risks
Learn More:
ARG Query:
Click the Azure Resource Graph tab to view the query
// Azure Resource Graph query
// Lists VMs with PIPs
resources
| where type =~ 'Microsoft.Network/publicIPAddresses'
| where tostring(properties.ipConfiguration.id) contains "microsoft.network/networkinterfaces"
| project recommendationId="1adba190-5c4c-e646-8527-dd1b2a6d8b15", name, id, tags, param1=strcat("Migrate from instance IP to NAT Gateway")
Basic SKU のパブリック IP アドレスを Standard SKU にアップグレードする
Impact: Medium Category: High Availability PG Verified: Verified
Description:
Basic SKU パブリック IP アドレスは、2025 年 9 月 30 日に廃止されます。ユーザーは、サービスの中断を避けるために、この日までに Standard SKU パブリック IP アドレスにアップグレードすることをお勧めします。
Potential Benefits:
Avoids service disruption
Learn More:
ARG Query:
Click the Azure Resource Graph tab to view the query
// Azure Resource Graph query
// List Basic SKU public IP addresses
Resources
| where type =~ "Microsoft.Network/publicIPAddresses"
| where sku.name =~ "Basic"
| project recommendationId = "5cea1501-6fe4-4ec4-ac8f-f72320eb18d3", name, id, tags, param1 = strcat("sku: ", sku.name)
パブリック IP アドレスでは DDoS 保護を有効にする必要があります
Impact: Medium Category: Security PG Verified: Verified
Description:
DDoS 攻撃は、インターネット経由で公的にアクセス可能なあらゆるエンドポイントを標的にする可能性があります。
Potential Benefits:
Avoids service disruption
Learn More:
ARG Query:
Click the Azure Resource Graph tab to view the query
// Azure Resource Graph query
// Public IP addresses should have DDoS protection enabled
resources
| where type =~ 'Microsoft.Network/publicIPAddresses'
| where properties.ddosSettings.protectionMode !in~ ("Enabled", "VirtualNetworkInherited")
| project recommendationId="c4254c66-b8a5-47aa-82f6-e7d7fb418f47", name, id, tags, param1=strcat("Apply either DDoS Network protection or DDoS IP Protrection to the public IP address.")